#include <Wire.h>
#include <BH1750.h>
#include <WiFiS3.h>
#include <time.h>
#include <LiquidCrystal_I2C.h>

// 기기 ID 설정
const char* deviceId = "arduino-002";

// WiFi 설정
const char* ssid = "와이파이 아이디";
const char* password = "와이파이 비밀번호";

// API 엔드포인트
const char* API_ENDPOINT = "엔드포인트";
const char* HOST = "호스트";

// 임계값 설정
const int LUX_THRESHOLD = 200;

BH1750 lightMeter;

unsigned long previousMillis = 0;
const long interval = 10000; // 10초
unsigned long wifiCheckMillis = 0;
const long wifiCheckInterval = 30000; // 30초 간격으로 WiFi 상태 확인


// LCD 핀 설정
LiquidCrystal_I2C lcd(0x27, 16, 2);  // I2C 주소는 0x27로 가정, LCD는 16x2

void setup() {
  Serial.begin(9600);
  Wire.begin();

  if (!lightMeter.begin()) {
    Serial.println(F("BH1750 initialization failed"));
    while (1);
  }
  
  Serial.println(F("BH1750 Test"));

  // WiFi 연결 설정
  connectToWiFi();

  // LCD
  lcd.init();
  lcd.backlight();  // 백라이트 켜기  
  // LCD 초기화
  lcd.begin(16, 2);  // LCD의 열과 행 수를 설정
}

void loop() {
  unsigned long currentMillis = millis();

  // 10초마다 조도값 읽고 서버로 전송
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;

    float lux = lightMeter.readLightLevel();
    Serial.print("Light: ");
    Serial.print(lux);
    Serial.println(" lx");

    String status = (lux <= LUX_THRESHOLD) ? "NOT_EXISTS" : "EXISTS";
    sendAlert(lux, status);  // HTTP 요청 전송
  }

  // 30초마다 WiFi 상태 확인
  if (currentMillis - wifiCheckMillis >= wifiCheckInterval) {
    wifiCheckMillis = currentMillis;
    checkWiFiConnection();
  }
}

void connectToWiFi() {
  // WiFi 모듈 체크
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    while (true);
  }

  // 이미 연결되어 있다면 반환
  if (WiFi.status() == WL_CONNECTED) {
    return;
  }

  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }

  lcd.setCursor(0, 0);  // 첫 번째 줄 첫 번째 칸으로 커서 이동    
  lcd.print("Connectiong to WIFI..");  // 첫 줄 출력  

  // WiFi 네트워크에 연결 시도
  Serial.print("Attempting to connect to WPA SSID: ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);

  // 연결 대기
  int retries = 10;
  while (WiFi.status() != WL_CONNECTED && retries-- > 0) {
    delay(1000);
    Serial.print(".");
  }
  Serial.println("");

  if (WiFi.status() == WL_CONNECTED) {
    Serial.println("You're connected to the network");
  } else {
    Serial.println("Failed to connect to WiFi");
  }
}

void checkWiFiConnection() {
  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("WiFi not connected. Attempting to reconnect...");
    connectToWiFi();
  } else {
    Serial.println("WiFi is connected");
  }
}

void sendAlert(float lightLevel, String status) {
  connectToWiFi();

  if (WiFi.status() != WL_CONNECTED) {
    Serial.println("WiFi not connected. Cannot send alert.");
    return;
  }

  WiFiClient client;
  
  if (!client.connect(HOST, 80)) {
    Serial.println("Connection to server failed");
    return;
  }

  String payload = "{\"lux\": " + String(lightLevel) + ", \"deviceId\": \"" + deviceId + "\", \"status\": \"" + status + "\"}";
  
  client.println("POST " + String(API_ENDPOINT) + " HTTP/1.1");
  client.println("Host: " + String(HOST));
  client.println("User-Agent: ESP32");
  client.println("Content-Type: application/json");
  client.print("Content-Length: ");
  client.println(payload.length());
  client.println();
  client.println(payload);

  lcd.clear(); // LCD 초기화
  lcd.setCursor(0, 0);  // 첫 번째 줄 첫 번째 칸으로 커서 이동    
  lcd.print("lux: " + String(lightLevel));  // 첫 줄 출력  

  lcd.setCursor(0, 1);  // 두 번째 줄 첫 번째 칸으로 커서 이동
  lcd.print("status: " + status);  // 첫 줄 출력    

  // 응답 확인
  while (client.connected()) {
    String line = client.readStringUntil('\n');
    if (line == "\r") {
      Serial.println("Headers received");
      break;
    }
  }

  String response = client.readString();
  Serial.println("Response: " + response);

  client.stop();
}